Shader 动画的主要点在坐标变换，代码：

Shader "Custom/Grass" {
    Properties {
        _MainTex ("Grass Texture", 2D) = "white" {}
        _TimeScale ("Time Scale", float) = 1
    }

    SubShader{
        Tags{"Queue"="Transparent" "RenderType"="Opaque" "IgnoreProject"="True"}
        Pass{
            Tags{"LightMode"="ForwardBase"}

            ZWrite Off
            Blend SrcAlpha OneMinusSrcAlpha
            Cull Off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc" 

            sampler2D _MainTex;
            half _TimeScale;

            struct a2v {
                float4 vertex : POSITION;
                float4 texcoord : TEXCOORD0;
            };

            struct v2f {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
            };


            v2f vert(a2v v){
                v2f o;
                float4 offset = float4(0,0,0,0);
                offset.x = sin(3.1416 * _Time.y * clamp(v.texcoord.y-0.5, 0, 1))  * _TimeScale;
                o.pos = mul(UNITY_MATRIX_MVP, v.vertex + offset);
                o.uv = v.texcoord.xy;
                return o;
            }

            fixed4 frag(v2f i) : SV_Target{
                return tex2D(_MainTex, i.uv);
            }

            ENDCG
        }
    }
    FallBack Off
}

Shader中设置渲染队列为 Transparent， 如果需要batch场景中模型的话需要在 Tags 中加上 “DisableBatching=True”， 不允许批处理。
关闭深度写入 Zwrite off。 关闭剔除，渲染双面Cull Off。开启混合为了显示透明 Blend SrcAlpha OneMinusSrcAlpha。

vertex函数中， 必须把坐标转换成视觉空间， 所以我们把操作就集中在这里，我的想法是：
草是延 Y 轴生长的， 而且根不能动。所以，在判断当前的坐标有两种情况：
1， 如果 y 坐标靠近 0 时，我们认为他是根部，根部不需要改变。
2， 其他高度， y 需要沿着某个方向做来回的摇摆pingpong运动。

当把根部看做原点，草的运动可以当成正弦函数， 取坐标距离底部的距离做一个限制，使底部摆动小clamp(v.texcoord.y-0.5, 0, 1)。 clamp(x, a, b) 的作用时当 x< a时 x=a， 当x > b 时 x=b。
我们做一个x方向的偏移（也可以z），sin(3.1416 _Time.y clamp(v.texcoord.y-0.5, 0, 1))， _Time是一个时间变化量，最后在乘上一个我们偏移的最大距离 _TimeScale即可。
最后，把SV_POSITION寄存器中的坐标设置为原本的坐标vertex 加上便宜坐标offset 后的转换。